pkgname=telegrammer-git
pkgver=0.1
pkgrel=1
pkgdesc="A C++ API Gateway for Telegram Bots"
arch=('x86_64')
url="https://git.xeno.darksair.org/telegrammer.git"
license=('MIT')
groups=()
depends=('curl' 'openssl' 'glibc' 'gcc-libs')
makedepends=('git' 'cmake' 'gcc')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
replaces=()
backup=()
options=(!debug !strip)
source=('git+https://git.xeno.darksair.org/telegrammer.git'
        "sysusers-${pkgname%-git}.conf"
        "${pkgname%-git}.service")
noextract=()
sha256sums=('SKIP'
            'aeb4afd6632e44b29b23bba49693bb8bceb6eef8c13dd4cf9e3df76a07b6f5ad'
            '180cea0b5af6ee29c8dbaa339f5ee6da54b7ca164feed2d397e07a7bd4d21316')

pkgver()
{
	cd "$srcdir/${pkgname%-git}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build()
{
	cd "$srcdir/${pkgname%-git}"
    cmake -B build \
          -DCMAKE_BUILD_TYPE='Release' \
          -DCMAKE_INSTALL_PREFIX='/usr' \
          -Wno-dev .
    cmake --build build
}

package()
{
    install -Dm755 -t "$pkgdir/usr/bin" "${srcdir}/${pkgname%-git}/build/${pkgname%-git}"
    install -Dm644 "${srcdir}/sysusers-${pkgname%-git}.conf" "$pkgdir/usr/lib/sysusers.d/${pkgname%-git}.conf"
    install -Dm644 "${srcdir}/${pkgname%-git}.service" "$pkgdir/usr/lib/systemd/system/${pkgname%-git}.service"
}