# Maintainer: MetroWind

pkgname=probius-git
pkgver=0.1
pkgrel=1
pkgdesc='Self-hosted service status tracker'
arch=('x86_64')
url='https://git.xeno.darksair.org/probius'
license=('WTFPL')
depends=('c-ares' 'curl' 'gcc-libs' 'glibc' 'sqlite')
makedepends=('cmake' 'gcc' 'git')
provides=('probius')
conflicts=('probius')
backup=('etc/probius.yaml')
options=(!debug)

source=(
    'probius::git+https://git.xeno.darksair.org/probius.git'
    'probius.service'
    'probius.sysusers'
    'probius.yaml'
)
sha256sums=(
    'SKIP'
    'c16a0f6151f0c64681339ac131e07bde8707ab994ba5707d541c6fb1501cca0c'
    '0f57b093e9e0412f2bfaced764c27929a581e6cdaa2842c904701337959712ff'
    '9ec35ec50287a513c1d9af35b48d7a0647ccdf13016f6f97829abe6c7444c777'
)

pkgver()
{
    cd "$srcdir/probius"
    printf 'r%s.g%s' \
        "$(git rev-list --count HEAD)" \
        "$(git rev-parse --short=7 HEAD)"
}

build()
{
    cd "$srcdir"
    cmake -S probius -B build \
        -DCMAKE_BUILD_TYPE=None \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DBUILD_TESTING=OFF \
        -Wno-dev
    cmake --build build
}

package()
{
    install -Dm755 "$srcdir/build/probius" \
        "$pkgdir/usr/bin/probius"
    install -Dm644 "$srcdir/probius.yaml" \
        "$pkgdir/etc/probius.yaml"
    install -Dm644 "$srcdir/probius.service" \
        "$pkgdir/usr/lib/systemd/system/probius.service"
    install -Dm644 "$srcdir/probius.sysusers" \
        "$pkgdir/usr/lib/sysusers.d/probius.conf"
}